#!/bin/zsh
set -euo pipefail
HUB="https://espacio.fontis.com.ar"
APP="$HOME/Library/Application Support/EspacioClaroAgent"
TMP="$(mktemp -d -t espacio-claro-setup.XXXXXX)"
ZIP="$TMP/Espacio-Claro-macOS-latest.zip"
trap 'rm -rf "$TMP"' EXIT

clear
echo "ESPACIO CLARO / FONTIS OS"
echo "Instalador inteligente para macOS"
echo
printf "Mac: "; scutil --get ComputerName 2>/dev/null || hostname
printf "Arquitectura: "; uname -m
LATEST="$(curl -fsSL "$HUB/VERSION.txt" | tr -d '\r\n')"
echo "Version publicada: $LATEST"
echo

echo "> Descargando paquete vigente..."
curl -fL --progress-bar "$HUB/downloads/Espacio-Claro-macOS-latest.zip" -o "$ZIP"
echo "> Verificando SHA-256..."
EXPECTED="$(curl -fsSL "$HUB/downloads/Espacio-Claro-macOS-latest.sha256" | awk '{print $1}')"
ACTUAL="$(shasum -a 256 "$ZIP" | awk '{print $1}')"
[[ -n "$EXPECTED" && "$EXPECTED" == "$ACTUAL" ]] || { echo "ERROR: la verificacion SHA-256 fallo."; read -k 1 "?Presiona una tecla para cerrar..."; exit 1; }
mkdir -p "$TMP/pkg"
unzip -q "$ZIP" -d "$TMP/pkg"
PKG="$(find "$TMP/pkg" -mindepth 1 -maxdepth 1 -type d | head -1)"
[[ -n "$PKG" ]] || { echo "ERROR: paquete invalido."; exit 1; }

if [[ ! -f "$APP/config.json" ]]; then
  echo
  echo "ALTA DE MAC NUEVA"
  echo "Se solicitara el token de alta una sola vez."
  chmod +x "$PKG/configurar.command"
  "$PKG/configurar.command"
else
  echo "> Esta Mac ya esta registrada; se conservara su configuracion."
fi

chmod +x "$PKG/instalar-launchagent.command"
echo "> Instalando/actualizando Espacio Claro..."
"$PKG/instalar-launchagent.command"
echo
echo "ESPACIO CLARO LISTO"
echo "La instalacion tecnica queda en: $APP"
read -k 1 "?Presiona una tecla para cerrar..."
echo